/* The trip.

A group of students are members of a club that travels annually to different
locations. Their destinations in the past have included Indianapolis, Phoenix,
Nashville, Philadelphia, San Jose, and Atlanta. This spring they are planning a
trip to Eindhoven.

The group agrees in advance to share expenses equally, but it is not practical
to share every expense as it occurs. Thus individuals in the group pay for
particular things, such as meals, hotels, taxi rides, and plane tickets. After
the trip, each student's expenses are tallied and money is exchanged so that
the net cost to each is the same, to within one cent. In the past, this money
exchange has been tedious and time consuming. Your job is to compute, from a
list of expenses, the minimum amount of money that must change hands in order
to equalize (within one cent) all the students' costs.

Input

Standard input will contain the information for several trips. Each trip
consists of a line containing a positive integer n denoting the number of
students on the trip. This is followed by n lines of input, each containing the
amount spent by a student in dollars and cents. There are no more than 1000
students and no student spent more than $10,000.00. A single line containing 0
follows the information for the last trip.

Output

For each trip, output a line stating the total amount of money, in dollars and
cents, that must be exchanged to equalize the students' costs.

Sample Input

3
10.00
20.00
30.00
4
15.00
15.01
3.00
3.01
0

Sample Output

$10.00
$11.99
*/

import std.stdio;
import std.algorithm;
import std.exception;
import std.array;
import std.math;


void main() {
    int nStudents;
    double[][] inputData;
    while (readf("%d\n", &nStudents) && nStudents != 0) {
        enforce(nStudents <= 1000, "There is no more then 1000 students");

        double[] expenses;
        foreach (n; 0 .. nStudents) {
            double expense;
            assert(readf("%f\n", &expense), "Invalid input data");
            enforce(expense <= 10_000.0,
                    "There is no student spent more then $10,000.00");

            expenses ~= expense * 100;
        }
        inputData ~= expenses;
    }

    writeln();

    foreach (data; inputData) {
        auto avg = reduce!("a + b")(0.0, data) / data.length;
        auto minAvg = floor(avg);
        auto maxAvg = ceil(avg);

        auto debit = 0.0;
        auto credit = 0.0;
        foreach (d; data) {
            if (d < maxAvg) {
                debit += minAvg - d;
            } else {
                credit += d - maxAvg;
            }
        }
        writefln("$%.2f", max(credit, debit) / 100);
    }
}