1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
.code16
.text
.org 0
start:
cli
lss %cs:STKPTR, %sp
sti
#сброс PIC
mov $0x20, %al #помещаем 20 в четные порты
outb $0x20
outb $0xA0
call init_bios #инициализация bios
#очистить экран
mov $0x3, %ax
int $0x10
call init_keyboard #инициализация клавиатуры
call init_timer #инициализация таймера
call init_pic #инициализация PIC
#программа раскладывает числа по старшему байту и делает так чтобы кол-во чисел с разными старшими байтами было одинаково для каждого байта
#0x20 кол-во элементов которые поступили
#0x22 прежнее значение таймера
#0x24 указатель на текущий элемент
#0x30-0x40 буфер для вывода
#инициализация буфера
mov $0x40, %dx
mov %dx, %es
#обнуляем область для данных
xorl %eax, %eax
mov $0x40, %cx
xorw %di, %di
cld
rep stosb #тут будут кол-ва выведенных чисел, среднее кол-во, предыдущее значение, текущий элемент очереди, и сама очередь
movw $0x30, %es:0x24 #адрес тек. эл-та очереди
circle:
call print
jmp circle
call stop
s: .asciz " "
#функция для основной работы
print:
mov $0x40, %dx
mov %dx, %ds
cli #запретить прерывание
movw %ds:0x24, %si
cmp $0x30, %si
jz q1 #если очередь не пуста
sub $0x2, %si #указатель на предыдущий
movw %ds:(%si), %ax %ax значение которое будем печатать
movw %si, %ds:0x24
sti #разрешили
#печать из %ax
pushw %ax
pushw $0x12 # 0x11 - BYTE, 0x12 - word
int $0x60
add $4, %sp
pushw %cs
pushw $s
pushw $1
pushw $1 # 1 - asciz cs:s length:1
int $0x60
add $8, %sp
q1: sti
ret
STKPTR: .word 0xFFFE, 0x9000
init_bios:
mov $0xC000, %dx
begins: mov %dx,%ds
xor %ax, %ax
cmpw $0xAA55, %ds:0
jnz adding
call scanbios
movzbw %ds:2,%ax
shl $5,%ax
add $0x7F,%ax
and $0xFF80, %ax
jmp noadd
adding:add $0x80,%ax
noadd:add %ax,%dx
cmpw $0xF000,%dx
jnae begins
ret
scanbios:
xorw %si, %si
xorw %cx, %cx
movb %ds:2, %ch
xorb %bl, %bl
chcksm: lodsw
addb %ah, %al
addb %al, %bl
decw %cx
jnz chcksm
or %bl, %bl
jnz skip
pusha
push %ds
push %es
push %fs
push %gs
push %cs
pushw $__ret
push %ds
pushw $3
lret
__ret:
pop %gs
pop %fs
pop %es
pop %ds
popa
skip:ret
init_keyboard:
xor %ax, %ax
mov %ax, %es
#установка вектора прерываний
movw $i09_handler, %es:0x09*4
mov %cs, %es:0x09*4+2
#сброс и автотест
mov $0x64, %dx #порт
mov $0xAA, %bx #код
mov $0x55, %si #ответ
call keyfunc
#тест синхронизации
mov $0xAB, %bx #код
mov $0x00, %si #ответ
call keyfunc
#разрешить сканирование
movb $0xAE, %al
outb $0x64
#сброс и тест
mov $0x60, %dx #порт
mov $0xFF, %bx #код
mov $0xFA, %si #ответ
call keyfunc
mov $0xAA, %si
call keyanswer
#разрешить клавиатуру
mov $0x60, %dx #порт
mov $0xF4, %bx #код
mov $0xFA, %si #ответ
call keyfunc
ret
#%si: хороший ответ
#%bl: запрос
#%dl: порт
#кидаем в порт
keyfunc:
mov $0xFFF0, %cx
w0: inb $0x64
testb $2, %al
jz w1
loop w0
jmp stop
w1: mov %bx, %ax
outb %dx
keyanswer:
mov $0x2000, %cx
w2: inb $0x64
testb $1, %al
jz w3
inb $0x60
cmpw %ax, %si
jz w4
mov $0x2000, %cx
w3: loop w2
call stop
w4: ret
i09_handler:
push %ax
push %bx
push %dx
push %si
push %di
push %cx
mov $0xAD, %al #запрет сканирования
outb $0x64
mov $0x40, %ax
mov %ax, %ds
inb $0x60 #получение символа в %al
testb $0x80, %al #нету прерываний на отпускание
jnz err9
movb $0x86,%al #10 2 channel, 00 zapomnit counter, dalee kak ranshe
outb $0x43
inb $0x42
movb %al,%ah
inb $0x42
xchg %ah,%al
ax текущий таймер
#0x20 кол-во элементов которые поступили
#0x22 прежнее значение таймера
#0x24 указатель на текущий элемент
#0x30-0x40 буфер для вывода
mov $0x40, %dx
mov %dx, %ds
movw %ds:0x24, %si
cmp $0x40, %si #переполнен ли стек
jz err9
movw %ds:0x20, %cx %cx количество элементов
add $0x10, %cx #если добавим еще элемент и получим какое среднее кол-во элементов мб после добавления 2^4-16 возможностей
shr $0x4, %cx
mov %ax, %di
subw %ds:0x22, %di %di разность
#mov %di,%dx
shr $0xC, %di #*"***0 старшими 4 битами определяем распределение чисел
shl $0x1, %di
#shr $12, %ax #*"***0
#shl $1, %ax
movw %ds:(%di), %bx
inc %bx %bx кол-во чисел с такой маской
cmp %cx, %bx
ja err9
movw %bx, %ds:(%di) #сохраним новое кол-во элементов
incw %ds:0x20 #увеличили текущее кол-во элементов
movw %ax, %ds:0x22 #прежнее значение таймера
#movw %dx, %ds:(%si)
movw %ax, %ds:(%si) #сохранить значение таймера на вывод
addw $0x2, %ds:0x24 #переместить указатель на следующий
err9:mov $0x20, %al #заверщение прерывания, в PIC0
outb $0x20
mov $0xAE, %al #разрешить сканирование
outb $0x64
pop %cx
pop %di
pop %si
pop %dx
pop %bx
pop %ax
iret
init_timer:
inb $0x61
or $0b00000001, %al #включаем второй канал
and $0b11111101, %al #отключаем спикер
outb $0x61
movb $0xB6,%al #10 2channel, 11 oba bayta,011 3 rezhim, 0 binarn counter
outb $0x43
mov $0xFF, %al #установка предела генерирования
outb $0x42
mov $0xFF, %al
outb $0x42
ret
init_pic:
#сброс пик
mov $0x20, %al
outb $0x20
outb $0xA0
#загрузка управляющих слов и маскирование прерываний
mov $0x11, %al
outb $0x20
outb $0xA0
mov $0x08, %al
outb $0x21
mov $0x70, %al
outb $0xA1
mov $0x04, %al
outb $0x21
mov $0x02, %al
outb $0xA1
mov $0x05, %al
outb $0x21
mov $0x01, %al
outb $0xA1
mov $0xFC, %al
outb $0x21
mov $0xFF, %al
outb $0xA1
ret
stop:
cli
hlt
jmp stop
.org 0xFFF0
.byte 0xEA
.word start
.word 0xF000
.org 0xFFFE
.word 0x99FC
.end